hspice model files for TSMC RF CMOS 0.18um

[kondou]

It is my first time use TSMC 0.18um RF model, I want to run hspice simluation. However I put the model name "nmos_rf" after mos in the netlist.

**************************************
.SUBCKT nmos_rf D G S B lr=18.E-08 nr=64 wr=1.5E-6
.param Lspace=0.54u
.param Ledge=2.6u
.param Ledgeeff=0.97u
.param Lsti=1.84u
.param Wsti=3.37u
.param Rod=2570
.param Rsti=4597
.param Ns='int(nr/2+1)'
.param Nd='int((nr+1)/2)'
.param Lod='nr*(lr+Lspace)+2*Ledge-Lspace'
.param rb='(Rod*Lod/12+Rsti*Lsti/2)*(Rod*wr/12+Rsti*Wsti/2)/(Lod*(Rod*Lod/12+Rsti*Lsti/2)+wr*(Rod*wr/12+Rsti*Wsti/2))'
.param rdb='Rod*lr/(wr*nr*2)'
*********************
RG G GI R='(0.539*wr/nr/lr+0.146/nr/(lr*1e6)+17.86/nr+584.9*lr/nr/wr+3.4'
RS S SI R='(0.0325*(lr*1e6+0.54)*(2*Ns+1/Ns-3) +8.666/Ns + 0.4485)/(wr*1e6)'
RD D DI R='0.005417*(lr*1e6+0.54)*(Nd+2/Nd) + 0.0929*(wr*1e6+2.94)/Nd + 1.625/(1.43+(Nd-1)*(lr*1e6+0.54))'
*********************
CGS_M GI SI C='(1.649*nr*(lr*1e6+0.54)/(0.1*wr*1e6+4)+0.158*wr*1e6+0.737)*1e-15'
CGD_M GI DI C='(0.181*nr*lr*1e6+0.153*nr+0.331)*1e-15'
CDS_M SI DI C='(0.0713+0.0842*nr*wr*1e6/(lr*1e6+0.9)+1.051*nr*(lr*1e6+0.54)/(wr*1e6+9.)*1e-15'
***** Diodes ****************
DSS SB SI ndio_rf_f AREA = '(Ns-2)*wr*Lspace+2*wr*Ledgeeff+(nr-int(nr/2)*2)*wr*(Lspace-Ledgeeff)'
+ PJ='(Ns-2)*Lspace*2+2*(2*Ledgeeff+wr)+(nr-int(nr/2)*2)*(2*(Lspace-Ledgeeff)-wr)'
DDD DB DI ndio_rf_f AREA = 'int(nr/2)*wr*Lspace+(nr-int(nr/2)*2)*wr*Ledgeeff'
+ PJ='int(nr/2)*Lspace*2+(nr-int(nr/2)*2)*(2*Ledgeeff+wr)'
DSG SB SI ndio_rf_g AREA = 1E-15 PJ = 'wr*nr'
DDG DB DI ndio_rf_g AREA = 1E-15 PJ = 'wr*nr'
************************************************** ***************************
RB B BI R='rb'
CB B BI C='159f/rb'
Rdb DB BI R='rdb'
Cdb DB BI C='159f/rdb'
Rsb SB BI R='rdb'
Csb SB BI C='159f/rdb'
******* MOSFET *******
M0 DI GI SI BI nch_rf L = lr W = wr M = nr AD = 0 AS = 0 PD = 0 PS = 0

.MODEL nch_rf.1 NMOS ( LMIN = 1.8e-007 LMAX = '5.001E-07'
+WMIN = '1.5000E-06' WMAX = '8.001E-06'
+LEVEL = 49 TNOM = 25.0 VERSION = 3.24
+TOX = 'toxn_RF'
+TOXM = 4.08E-09
+XJ = 1.6000000E-07
+NCH = 3.9000000E17 LLN = -1 LWN = 1.0000000
+WLN = 1.0000000 WWN = -1 LINT = 1.0000000E-08
+LL = 0.00 LW = 0.00 LWL = 0.00
+WINT = 3.0000000E-09 WL = 0.00 WW = 0.00
+WWL = 0.00 MOBMOD = 1 BINUNIT = 2
+XL = '-0.02E-6+dxln_RF' XW = '0.0+dxwn_RF' DWG = 0.00
+DWB = 0.00 ACM = 12 LDIF = 9.00E-08
+HDIF = 'hdifn_RF' RSH = 'rshn_RF' RD = 0
+RS = 0

*****************************************

what mos model name should I use? I test nmos_rf and nch_rf, but it doesn't work.
error message => nmos_rf not defined!

Any help would be appreciated !

 

[himansg]

.MODEL nch_rf.1 NMOS ( LMIN = 1.8e-007 LMAX = '5.001E-07'

Why have you written "nch_rf.1" instead of "nch_rf" ??
I think that why you are getting error ....
while you have used nch_rf here.....

M0 DI GI SI BI nch_rf L = lr W = wr M = nr AD = 0 AS = 0 PD = 0 PS = 0

 

[pancho_hideboo]

Why have you written "nch_rf.1" instead of "nch_rf" ??
I think that why you are getting error ....

No.
This is for "binning" of (LMIN = 1.8e-007 LMAX = '5.001E-07' WMIN = '1.5000E-06' WMAX = '8.001E-06').
So this "nch_rf.1" is proper.

"nmos_rf" has to be refered as subcircut, that is, "X#" instance not "M#" instance.

.SUBCKT nmos_rf D G S B lr=18.E-08 nr=64 wr=1.5E-6

 

[kondou]

thanks for your help!