Anyone have spice model for TLP281 or TLP291 (TOSHIBA photocoupler)?

[Julia2013]

Hi All:


Google search turns out nothing except one website selling it which costs several hundred dollars!


I would like to extract the spice model if I have enough time to learn...


Just to see if I will be lucky enough to get one?


They are photocouplers from TOSHIBA.

I have searched the whole toshiba website but get no model at all.



Thank you a lot.

 

[FvM]

PSpice has a number of industry standard optocoupler models in OPTO.lib. It's not obvious however, if this (or any other library) represents all intended parameters, e.g. dynamical behaviour. Before searching for models, you should have an idea which parameters should be modelled. In some cases, it might be more promising to setup a simple behavioral model covering the parameter of interest.

*******************************************************************************
* A = diode anode
* K = diode cathode
* C = BJT collector
* B = BJT base
* E = BJT emitter
.SUBCKT CNY17-1 A K C B E PARAMS: REL_CTR=1
* CNY17-1 from Motorola Optoelectronics data book Q3/93  -  RPerez
D1 A D DCNY17   ;Gallium arsenide infrared emitting diode
Vsense D K 0    ;Diode Current sense -> IF
Hd   R 0 Vsense 1
Rd   R T 10K
Cd   T 0 0.15n
* Gpcg models CTR 
Gpcg C B TABLE  ;Photodetector {IC@IF * (normalized CTR at IF)*REL_CTR/(Q1 BF)
+ {6m*(0.9277*V(T)^3-1.2381*V(T)^2+100.4332*V(T)-0.02771)*REL_CTR/400}
+ (0,0) (10,10)
Q1 C B E E QCNY17   ;phototransistor detector
.model DCNY17 D IS=1P N=1.948621 RS=1.560495 BV=6 IBV=10U
+ CJO=18.8P VJ=0.532794 M=0.27985 EG=1.424 TT=500N
* ISC controls dark current
* IKF controls high current gain
.model QCNY17 NPN IS=3.64P BF=400 NF=1.193293 BR=10 TF=2N TR=350n
+ CJE=5.16P VJE=0.99 MJE=0.2411274 CJC=18P VJC=0.597478 MJC=0.431978
+ ISC=0.207N VAF=65 IKF=0.09 ISS=0 CJS=7.74p VJS=0.61 MJS=0.31
.ends
*$
*******************************************************************************
* A = diode anode
* K = diode cathode
* C = BJT collector
* B = BJT base
* E = BJT emitter
.SUBCKT CNY17-2 A K C B E PARAMS: REL_CTR=1
* CNY17-2 from Motorola Optoelectronics data book Q3/93  -  RPerez
D1 A D DCNY17   ;Gallium arsenide infrared emitting diode
Vsense D K 0    ;Diode Current sense -> IF
Hd   R 0 Vsense 1
Rd   R T 10K
Cd   T 0 0.25n
* Gpcg models CTR 
Gpcg C B TABLE  ;Photodetector {IC@IF * (normalized CTR at IF)*REL_CTR/(Q1 BF)
+ {10m*(0.9277*V(T)^3-1.2381*V(T)^2+100.4332*V(T)-0.02771)*REL_CTR/400}
+ (0,0) (10,10)
Q1 C B E QCNY17   ;phototransistor detector
.model DCNY17 D IS=1P N=1.948621 RS=1.560495 BV=6 IBV=10U
+ CJO=18.8P VJ=0.532794 M=0.27985 EG=1.424 TT=500N
* ISC controls dark current
* IKF controls high current gain
.model QCNY17 NPN IS=3.64P BF=400 NF=1.193293 BR=10 TF=1N TR=30n
+ CJE=5.16P VJE=0.99 MJE=0.2411274 CJC=18P VJC=0.597478 MJC=0.431978
+ ISC=0.207N VAF=65 IKF=0.09 ISS=0 CJS=7.74p VJS=0.61 MJS=0.31
.ends
*$
*******************************************************************************
* A = diode anode
* K = diode cathode
* C = BJT collector
* B = BJT base
* E = BJT emitter
.SUBCKT CNY17-3 A K C B E PARAMS: REL_CTR=1
* CNY17-3 from Motorola Optoelectronics data book Q3/93  -  RPerez
D1 A D DCNY17   ;Gallium arsenide infrared emitting diode
Vsense D K 0    ;Diode Current sense -> IF
Hd   R 0 Vsense 1
Rd   R T 10K
Cd   T 0 0.27n
* Gpcg models CTR 
Gpcg C B TABLE  ;Photodetector {IC@IF * (normalized CTR at IF)/(Q1 BF)
+ {15m*(0.9277*V(T)^3-1.2381*V(T)^2+100.4332*V(T)-0.02771)*REL_CTR/400}
+ (0,0) (10,10)
Q1 C B E QCNY17   ;phototransistor detector
.model DCNY17 D IS=1P N=1.948621 RS=1.560495 BV=6 IBV=10U
+ CJO=18.8P VJ=0.532794 M=0.27985 EG=1.424 TT=500N
* ISC controls dark current
* IKF controls high current gain
.model QCNY17 NPN IS=3.64P BF=400 NF=1.193293 BR=10 TF=13N TR=375n
+ CJE=5.16P VJE=0.99 MJE=0.2411274 CJC=18P VJC=0.597478 MJC=0.431978
+ ISC=0.207N VAF=65 IKF=0.09 ISS=0 CJS=7.74p VJS=0.61 MJS=0.31
.ends
*$