Why var is not taking value as per constraint

[jdshah]

class Base;
rand integer vari;
  constraint range { 0< vari < 100 ;}
endclass

module test;
  Base objh =new();
initial
begin
if(objh.randomize())
begin
$display(" Randomization is done ");
end
  $display(" objh.baseh.vari : %d ", objh.vari );
end
endmodule

Output : objh.vari : 1245020823

My question is constraint did not failed, but value did not generated as per constraint. Why?
The reason I find out is, this happened as constraint are declarative. But I did not understood the reason. Can anyone explain?

 

[TrickyDicky]

I dont think 0 < vari < 100 is valid syntax

try:

constraint range { vari > 0;
                   vari < 100; }

 

[jdshah]

I dont think 0 < vari < 100 is valid syntax

try:

constraint range { vari > 0;
                   vari < 100; }

Yeah that will work. But I want to know why this is not working

 

[dave_59]

It is valid syntax, but your constraint expression is evaluated like any other expression, with left to right association: ( ( 0 < vari ) < 100 ). Since the result of ( 0 < vari ) can only be 0 or 1 for any value of vari, your constraint expression is satisfied for any value of vari. Some tools have verbose solve modes that would show you this.

For ranges or set of values, I recommend using the inside operator (LRM section 18.5.3 Set membership ) instead:

constraint range { vari inside {[1:99];}

 

[jdshah]

It is valid syntax, but your constraint expression is evaluated like any other expression, with left to right association: ( ( 0 < vari ) < 100 ). Since the result of ( 0 < vari ) can only be 0 or 1 for any value of vari, your constraint expression is satisfied for any value of vari. Some tools have verbose solve modes that would show you this.

For ranges or set of values, I recommend using the inside operator (LRM section 18.5.3 Set membership ) instead:

constraint range { vari inside {[1:99];}

Thanks Dave for explanation.
Why constraint is evaluated like this. Is it because it is declarative? Is there any connection with that?

 

[dave_59]

There is no connection with whether the constraints are declarative or not. You wrote a expression that always evaluates to true (1'b1). Consider a plain-old Verilog example that does the same thing without any constraint solver.

module test;
  integer vari;
  `define RANGE  (0< vari < 100 )
  initial begin
      vari = $random;
      while ( ! `RANGE )
             vari = $random; // never executes 
      $display(" Randomization is done ");
      $display("vari : %d ", vari );
  end
endmodule

The while loop never executes its body because the while expression is always false, because `RANGE is always true. The value of vari is irrelevant to the expression. If you change RANGE to ((vari > 0) && (vari < 100)), then you will eventually get a value that satisfies the constraint.

But there are a number of problems with this procedural method of generating a random number. Assuming you wrote a meaningful constraint, there is no guarantee that $random will ever generate a value that satisfies the constraint. Or it could take a very long time before generating that value. And if you wrote a constraint that had no possible solutions, there would be no way to know that unless you exhaustively tried every value. Add to this a number of random variables with interdependent constraints and the problem becomes insurmountably.

That's where the declarative nature of the constraint solver comes in to play. It analyzes all the constraints together and comes up with an algorithm to generate values for all the random variables in what seems like a single step. Unfortunately, this makes it difficult to debug because you can't see all the intermediate constraint expression results.

But conceptually, you can sill think of the constraint solver as exhaustively trying every possible combination random values, then building a solution set of values that satisfies the constraints. When you call randomize() it just picks one of those randomly from the set.