Help to plot gm/id vs id/W

[doibongvui]

Hi
I need some one help me how to plot gm/id vs id/W. I include my spice deck if someone see any error please correct it

$ gm/id vs inom plots

.lib "C:\synopsys\Hspice_A-2007.09\test\spice_model.lib" TT

.options post nomod
.param w1=1u
ibias vdd d dc 0
vvdd vdd 0 dc 3v

mn1 d d 0 0 nmos W=w1 L=0.3u

.op
.dc ibias 0 10u 0.1u

.probe gm_id=par('gmo(mn1)/i(mn1)')
.probe id_w=par('i(mn1)/W(mn1)')

.print i(mn1)

.alter
.param w1=2u
.alter
.param w1=3u
.alter
.param w1=4u

.end


I also have question how to plot many graphs on the same window. I want to see the difference of curve when width changes.

Thanks a lot

 

[baenisch]

Hi there

Looks just like a problem with i(mn0) for me
I don't now what kind of model you're using
but at least for BSIM3/4 you need to probe
ids(nm0) and not i(nm0). Depends also on how
HSpice is handling internal spice variables ...

Best Regards

Andi

 

[pickpunk]

You can use Murmann's spice deck:

* DC sweep for technology characterization

* Boris Murmann, 2008



.inc 'cmos018.sp'

.param length=0.18u

.param width=5u

.param ds=0.9

.param gs=1



vdsn vdn 0 dc 'ds'

vgsn vgn 0 dc 'gs'

mn vdn vgn 0 0 nch L='length' W='width'

vdsp vdp 0 dc '-ds'

vgsp vgp 0 dc '-gs'

mp vdp vgp 0 0 pch L='length' W='width'



.op

.options dccap post brief

.dc gs 0.2V 1.2V 10mV length 0.18u 0.5u 0.02u



************** IMPORTANT *********************

* IF YOU WANT TO RE-USE THIS CODE FOR BSIM4 MODELS,

* THE PARAMETER EXTRACTION BELOW MUST BE PROPERLY

* ADJUSTED. E.G. THE TOTAL GATE CAP FOR BSIM4 IS

* CALLED "CGGBM" (INSTEAD OF CGGB0). PLEASE CONSULT

* THE HSPICE MANUAL.



.probe nth = par('vth(mn)')

.probe ngm = par('gmo(mn)')

.probe ncgg = par('cggbo(mn)')

.probe ncgd = par('cgdbo(mn)')

.probe ncdd = par('cddbo(mn)')

.probe ncdg = par('cdgbo(mn)')

.probe ngds = par('gdso(mn)')

.probe nidw = par('i(mn)/width')



.probe pth = par('vth(mp)')

.probe pgm = par('gmo(mp)')

.probe pcgg = par('cggbo(mp)')

.probe pcgd = par('cgdbo(mp)')

.probe pcdd = par('cddbo(mp)')

.probe pcdg = par('cdgbo(mp)')

.probe pgds = par('gdso(mp)')

.probe pidw = par('i(mp)/width')



.end