[SOLVED] 3 gate oscillator output waveform is okay in TSpice but not in HSPICE

[shockingshockley]

When I ran the code below in TSPICE, a 5V pulse waveform was generated. However when I ran it in HSPICE, a 2.5V dc straight line waveform is generated. Do I need to modify some code to generate a pulse waveform in HSPICE? Thank you!

*3 GATE OSC
.PROTECT
.LIB 'C:\Users\MM0355V.L' TT_5V
.UNPROTECT

 
.SUBCKT INV A OUT VDD VSS
MN1 Out A VSS 104 NCH5 W=1u L=0.4U 
MP1 Out A Vdd VDD PCH5 W=2U L=0.4U 
.ENDS

XUINV1 OSCIN 2 VDD VSS INV
XUINV2 2 V2 VDD VSS INV
XUINV3 V2 OSCOUT VDD VSS INV
R1 V1 OSCOUT 470K
R2 V1 OSCIN 470K
C1 V2 V1 120P
   

VDD VDD 0 DC 5
VSS VSS 0 DC 0
.TRAN 10U 5000U
.PRINT TRAN V(OSCOUT)
.END

 

[FvM]

The netlist can be expected to give a straight line in any simulator that performs a transient analysis according to the original SPICE methode. The initial transient solution finds an equilibrium and no stimulus is causing a deviation from this state. The most simple method to start an oscillation is to skip the initial transient solution

.TRAN 10U 5000U UIC

By the way, you're in good company. At least every second SPICE oscillator simulation thread at Edaboard is struggling with this basic problem.

 

[shockingshockley]

Thanks FvM! great help!

 

[dick_freebird]

Put a small current pulse "kicker" to it that will emulate
the natural noise stimulus. DC stable is a valid solution
absent noise.Simulators with different tolerances will
leave different "residues" in the initial solution which
can provide the "kick" (but fail to, often enough, that
you should not count on a stable DC solution magically
starting to oscillate on its own).

 

[FvM]

Kickstart is the other option, but not needed if you can use UIC.

 

[erikl]

... not needed if you can use UIC.

... or a fast switch-on of the power supply.