an urgent problem of HSPICE:' error: no convergence in operating point'

[Li Yupeng]

I have tried a simulation in HSPICE with a circuit composed of a ring oscillator( 601 CMOS converters),but failed.
The library I used is 350nm craft level.
The netlist is as follows:

.LIB 'D:\HSPICE_sim\SMIC35_SPICE\TD-MM35-SP-2002v5T\ASCII\ASCII\hspice\Enhanced_MS035_v0p6.lib' tt

.GLOBAL VSS VDD
.PARAM AEMI=0
.PARAM FEMI=1000MEG

*** Power Supply ***
VSUP	VDD0	VSS	1.2
VEMI	VDD	VDD0	SIN(0 AEMI FEMI 10n)
VGND	VSS	0	0
.NODESET	V(1)=0

*** Ring ***
XCH1		2	1	Chain200INVX1
XCH2		3	2	Chain200INVX1
XCH3		4	3	Chain200INVX1
XNOTFE		1	4	INVX1

*** Chain of 200 Inverters Ring ***
.subckt Chain200INVX1 11 1
XCHAIN1		2	1	Chain20INVX1
XCHAIN2		3	2	Chain20INVX1
XCHAIN3		4	3	Chain20INVX1
XCHAIN4		5	4	Chain20INVX1
XCHAIN5		6	5	Chain20INVX1
XCHAIN6		7	6	Chain20INVX1
XCHAIN7		8	7	Chain20INVX1
XCHAIN8		9	8	Chain20INVX1
XCHAIN9		10	9	Chain20INVX1
XCHAIN10	11	10	Chain20INVX1
.ends Chain20INVX1

*** Chain of 20 Inverters ***
.subckt Chain20INVX1 21 1
XNOT1	2	1	INVX1
XNOT2	3	2	INVX1
XNOT3	4	3	INVX1
XNOT4	5	4	INVX1
XNOT5	6	5	INVX1
XNOT6	7	6	INVX1
XNOT7	8	7	INVX1
XNOT8	9	8	INVX1
XNOT9	10	9	INVX1
XNOT10	11	10	INVX1
XNOT11	12	11	INVX1
XNOT12	13	12	INVX1
XNOT13	14	13	INVX1
XNOT14	15	14	INVX1
XNOT15	16	15	INVX1
XNOT16	17	16	INVX1
XNOT17	18	17	INVX1
XNOT18	19	18	INVX1
XNOT19	20	19	INVX1
XNOT20	21	20	INVX1
.ends Chain20INVX1

*** Standard Cell Inverter X1 ***
.subckt INVX1 Y A
M0 VDD A Y VDD p33 l=0.13u w=0.64u
M1 Y A VSS VSS n33 l=0.13u w=0.42u
.ends INVX1

*** simulation setup ***
.TRAN		0.05ns		400ns
.OPTION	INGOLD=1
.OPTION PROBE
.PROBE		v(1)


.ALTER
.PARAM AEMI=0.05
.ALTER
.PARAM AEMI=0.10
.ALTER
.PARAM AEMI=0.15
.ALTER
.PARAM AEMI=0.20
.ALTER
.PARAM AEMI=0.25
.ALTER
.PARAM AEMI=0.30
.ALTER
.PARAM AEMI=0.35
.ALTER
.PARAM AEMI=0.40
.ALTER
.PARAM AEMI=0.45
.ALTER
.PARAM AEMI=0.50
.END

any help is my expectation.

[gag2000]

Hi,
I ve not read your netlist in detail, but try to fix one net in start condition, at zero for example.
It should solve your problem, which is common with spice simulator.
Regards,
RG

[gag2000]

Syntax :
.INIT net voltage

[Li Yupeng]

Hi,
I ve not read your netlist in detail, but try to fix one net in start condition, at zero for example.
It should solve your problem, which is common with spice simulator.
Regards,
RG

hi!
I have exchanged " .NODESET V(1)=0" with ".IC V(1)=0", and finally succeeded. Thank you for your suggestion.