Need some help on simulating Quantum Cascade Laser using PSpice

[jacksontom]

I tried to build a simple QCL(quantum cascade laser) model based on 2-level rate equations in Pspice. The codes are as follows, but I can't get the right probe output. May someone give me some advice, please. your help will be very appreciated !

The codes:
QCL MODEL

Id 0 1 1A AC 0.5A
Itr 0 1 pulse(0 3A 0.05ns 0.05ns 0.05ns 5ns 10ns)
Xlaser 1 0 2 QCL
rout 2 0 1e9

.SUBCKT QCL N3 N0 OUT

***************************************************************
** Name: qcl.cir
**
** Purpose: simple qcl model based on 2-level rate equations in pspice
**
** References:
**
**
**
**
** Date: September 23, 2012
**
** Author: Xia Xiaojun
**
***************************************************************

** constants **************************************************
.PARAM pi = 3.1415926535898
.PARAM q = 1.60217733e-19 ; electronic charge..........[A s]
.PARAM kb = 1.380658e-23 ; boltzmann constant.........[J/K]
.PARAM c0 = 2.99792458e8 ; vacuum speed of light......[m/s]
.PARAM h = 6.6260755e-34 ; planck constant............[J s]
***************************************************************

** parameter **************************************************
**general physics parameter
.PARAM Rr = 0.27 ; right facet reflectivity
.PARAM Rl = 0.27 ; left facet reflectivty
.PARAM alpha_w = 13.3 ; waveguide losses [cm^(-1)]
.PARAM tau_3 = 1.3e-12 ; carrier lifetime on energy level 3
.PARAM tau_32 = 2.1e-12 ; transition between level 3 and level 2
.PARAM tau_21 = 4e-13 ; transition between level 2 and level 1
**gain parameter
.PARAM sigma_32 = 1.796e-14 ; differential gain cross section [cm^2]
.PARAM ng = 3.29 ; group refraction index
.PARAM gamma = 0.53 ; optical confinment factor [single gain stage]
**geometrical parameters
.PARAM L = 0.3 ; cavity length [cm]
.PARAM W = 1.17e-3 ; cavity width [cm]
.PARAM Lp = 4.53e-6 ; single gain stage thickness [cm]
.PARAM Ns = 25 ; #gain stages
*thermal parameters
.PARAM lambda = 5000 ; emission wavelength @300K [nm]
**calculated parameters
.PARAM vg = {100*c0/ng} ; group velocity [cm/s]
.PARAM alpha_m = {1/L*LOG(1/SQRT(Rr*Rl))} ; mirror losses
.PARAM tau_p = {1/(vg*(alpha_w + alpha_m))} ; photon lifetime for each mode
.PARAM Vcav = {Ns*L*W*Lp} ; active volume [cm^3]
.PARAM eta_opt = {alpha_m/(alpha_w + alpha_m)*(1-Rr)/
+ (1-Rr+(1-Rl)*SQRT(Rr/Rl))} ; optical power output coupling efficiency
.PARAM hvl = {h*c0/1e-9} ; photon energy [J*nm]
** arbitrary constants
.PARAM zn = 1e3
*.PARAM k = 1.5e-19
.PARAM del = 4.0e3
** for power calculations
.PARAM k_power = {hvl/lambda*eta_opt/tau_p}
***************************************************************

** netlist ****************************************************

** carrier numbers
RN3 N3 N0 {tau_3/(q*zn)}
CN3 N3 N0 {q*zn}
GN32 N3 N2 value={q*zn*vg*sigma_32*gamma*V(N3,N2)*(V(P)+del)*(V(P)+del)/(k_power*Vcav)}
RN2 N2 N0 {tau_21/(q*zn)}
CN2 N2 N0 {q*zn}
GN2 N0 N2 value={q*zn*V(N3)/tau_32}

** phonton numbers
GNP 0 P value={zn*tau_p*Ns*gamma*vg*sigma_32*V(N3,N2)*(V(P)+del)/Vcav-del}
RNP P 0 1
CNP P 0 {2*tau_p}

** output power
Eout OUT 0 value={(V(P)+del)*(V(P)+del)}

***************************************************************

.ENDS

.option list expand node opts
.op
.dc Id 0 5A 0.05A
.tran 0.05ns 20ns 0 0.01ns
.ac dec 100 0.1G 10G
.probe
.end




the images are electric model of QCL based on 2-level rate equations.
And the 2-level rate equations are as follows :


Also I have do some transform to the number of electrons and photons as follows:


Thanks !
gashyazh@126.com

 

[atripathi]

Output of Xlaser is available at node 2. You need to plot V(2). Attached is the picture representing the wavefrom. From your append it is not clear that if this what you are looking for



If you think simulation result is not accurate, then you need to explain what this model does, and how this has been implemented, for anyone to offer any help.

 

[jacksontom]

Yes, the outcome is available at node 2. It is the output photon power of the laser. We need the L-I curves of the laser which is the same as DC analysis in Pspice and should like this.


Also other two results should like this which is correspondence to AC analysis and transient analysis .

 

[atripathi]

You need to debug your model. I know this does not help much!