help add model into orcad 9.2

hello, currently I want to use MIC4451 in my circuit on orcad 9.2 capture.I have downloaded the MIC4451 model text file,but I don't know how to add it into my liberary.Can anyone give me a tip on this?please give me detailed procedure !
. thanks!
* Micrel MIC4451
* Revision: 3/1/05, version 1.1

.subckt MIC4451 4 3 9 2
* In Out Vcc Gnd
Rin 4 Vind 2k
C1 4 2 6P
D2 2 Vind DN
D3 4 9 DN
RT 4 2 10MEG

Vsctl 13 0 DC=5
XSctl 13 VindH Vind 2 SWhyste PARAMS: VT=1.2 VH=.1 RON=1 ROFF=1G
Rsctl VindH 2 1MEG

I2 9 2 DC=50u
R2 9 2 600k
I1 9 8 DC=215U
R4 9 8 150k
D4 8 9 DN
.MODEL DN D

EBLin 12 2 Value={ IF ( V(VindH) > 2 , 5 , 0 ) }
Rind 12 10 100
Cind 10 11 85p
Vinput 11 2
GBind 10 2 Value={ IF ( 12-V(9) > 0 , 0.3*I(Vinput)*(12-V(9)) , 0 ) }
XSinput 8 6 10 2 SWhyste PARAMS: VT=1.9 VH=.65 RON=1 ROFF=1G
Rinput 6 2 6k

EB3 7 3 Value={ IF ( V(8,2) < 0.5*V(9,2) , V(9,2) , -V(9,2) ) }
Rout 1 7 500

EVS 99 0 Value={ IF ( V(9)-4 < 1 , 1 , V(9)-4 ) }
XCout 99 0 98 1 2 yx
* Ctl Ref Cap+ -
Cref 98 0 1p

C2 3 2 1500p
MHS 9 1 3 3 _MHS_mod L=1U W=3.45u
MLS 2 1 3 3 _MLS_mod L=1U W=4.352u
.MODEL _MLS_mod PMOS KP=0.077 VTO=-1.3 RD=.565
.MODEL _MHS_mod NMOS KP=.074 VTO=.015 RD=.372
.ENDS
.subckt yx 1 2 3 4 5
ecopy 3 6 poly(2) (1,2) (4,5) 0 0 0 0 1
fout 4 5 vsense 1
rin 1 2 1G
vsense 0 6 0
.ends
.subckt SWhyste NodeMinus NodePlus Plus Minus PARAMS: RON=1 ROFF=100MEG VT=1.5 VH=.5
S5 NodePlus NodeMinus 8 0 smoothSW
EBcrtl 8 0 Value = { IF ( V(plus)-V(minus) > V(ref), 1, 0 ) }
EBref ref1 0 Value = { IF ( V(8) > 0.5, {VT-VH}, {VT+VH} ) }
Rdel ref1 ref 70
Cdel ref 0 100p IC={VT+VH}
Rconv1 8 0 10Meg
Rconv2 plus 0 10Meg
Rconv3 minus 0 10Meg
.model smoothSW VSWITCH (RON={RON} ROFF={ROFF} VON=1 VOFF=0)
.ends SWhyste

I have done it successful according to the following file.
Hope can help someone who have same problem.