Help me on opamp simulation

Hi,

I am simulating a two stage opamp and try to measure the settle time connected in unity gain feedback. But has problem to carry through. The problem is I couldn't get the expected output transient response in the waveform when there is a step in the input. Who could take one minute to look at the netlist and see if I am simulating in the correct way.

Thanks



* DATE: Jan 3/05
* Temperature_parameters=Default
.MODEL MODN NMOS ( LEVEL = 49
+VERSION = 3.1 TNOM = 27 TOX = 8.2E-9
+XJ = 1.5E-7 NCH = 1.7E17 VTH0 = 0.5298591
+K1 = 0.6335153 K2 = 0.0179106 K3 = -3
+K3B = 2.2527252 W0 = 1E-8 NLX = 1.151824E-7
+DVT0W = 0 DVT1W = 0 DVT2W = 0
+DVT0 = 1.0127147 DVT1 = 0.4406112 DVT2 = -0.1413729
+U0 = 469.5155494 UA = 1E-13 UB = 2.158509E-18
+UC = 5.912855E-11 VSAT = 1.303893E5 A0 = 1.5505826
+AGS = 0.2077944 B0 = -1.434702E-7 B1 = -1E-7
+KETA = -6.728324E-4 A1 = 0 A2 = 0.9285664
+RDSW = 939.7838273 PRWG = -1.9305E-14 PRWB = -0.0371976
+WR = 1 WINT = 4.209825E-8 LINT = 9.132222E-8
+DWG = 5.645762E-9 DWB = 3.180753E-9 VOFF = -0.15
+NFACTOR = 2.5 CIT = 0 CDSC = 2.4E-4
+CDSCD = 0 CDSCB = 0 ETA0 = 0.0827143
+ETAB = -0.0144051 DSUB = 0.7252479 PCLM = 0.577163
+PDIBLC1 = 2.155453E-3 PDIBLC2 = 3.899425E-3 PDIBLCB = 0.0730567
+DROUT = 0.0526631 PSCBE1 = 3.574991E8 PSCBE2 = 2.322837E-6
+PVAG = 0.1149111 DELTA = 0.01 RSH = 3.9
+MOBMOD = 1 PRT = 0 UTE = -1.5
+KT1 = -0.11 KT1L = 0 KT2 = 0.022
+UA1 = 4.31E-9 UB1 = -7.61E-18 UC1 = -5.6E-11
+AT = 3.3E4 WL = 0 WLN = 1
+WW = 0 WWN = 1 WWL = 0
+LL = 0 LLN = 1 LW = 0
+LWN = 1 LWL = 0 CAPMOD = 2
+XPART = 0.5 CGDO = 3.6E-10 CGSO = 3.6E-10
+CGBO = 1E-10 CJ = 1.00004E-3 PB = 0.8
+MJ = 0.3474434 CJSW = 1.093391E-10 PBSW = 0.8
+MJSW = 0.2009364 CJSWG = 1.64E-10 PBSWG = 0.99
+MJSWG = 0.2009364 CF = 0 PVTH0 = -2.288098E-3
+PRDSW = -22.0640861 PK2 = -2.804187E-3 WKETA = -1.643931E-3
+LKETA = -0.0108733 )
*
.MODEL MODP PMOS ( LEVEL = 49
+VERSION = 3.1 TNOM = 27 TOX = 8.2E-9
+XJ = 1.5E-7 NCH = 1.7E17 VTH0 = -0.4620588
+K1 = 0.9361918 K2 = -0.0176335 K3 = 0
+K3B = 7.0070366 W0 = 1E-8 NLX = 3.686611E-9
+DVT0W = 0 DVT1W = 0 DVT2W = 0
+DVT0 = 0.7858918 DVT1 = 0.6254556 DVT2 = -0.3
+U0 = 118.7814043 UA = 1.143307E-9 UB = 5.271874E-21
+UC = -1E-10 VSAT = 1.073506E5 A0 = 0.8695045
+AGS = 0.1080859 B0 = 1.10047E-6 B1 = 5E-6
+KETA = 0.0130719 A1 = 8.279283E-3 A2 = 0.3
+RDSW = 3E3 PRWG = -0.0987856 PRWB = -0.1874643
+WR = 1 WINT = 4.915837E-8 LINT = 5.439976E-8
+DWG = -2.575699E-8 DWB = 1.522097E-8 VOFF = -0.0361606
+NFACTOR = 0.8753188 CIT = 0 CDSC = 2.4E-4
+CDSCD = 0 CDSCB = 0 ETA0 = 0.1877525
+ETAB = -0.2 DSUB = 1 PCLM = 1.5235775
+PDIBLC1 = 3.633434E-3 PDIBLC2 = 3.617068E-4 PDIBLCB = -0.1
+DROUT = 0.0680148 PSCBE1 = 4.769363E10 PSCBE2 = 5E-10
+PVAG = 0 DELTA = 0.01 RSH = 3
+MOBMOD = 1 PRT = 0 UTE = -1.5
+KT1 = -0.11 KT1L = 0 KT2 = 0.022
+UA1 = 4.31E-9 UB1 = -7.61E-18 UC1 = -5.6E-11
+AT = 3.3E4 WL = 0 WLN = 1
+WW = 0 WWN = 1 WWL = 0
+LL = 0 LLN = 1 LW = 0
+LWN = 1 LWL = 0 CAPMOD = 2
+XPART = 0.5 CGDO = 3.58E-10 CGSO = 3.58E-10
+CGBO = 1E-10 CJ = 8.331881E-4 PB = 0.7351912
+MJ = 0.3387901 CJSW = 8E-13 PBSW = 0.75
+MJSW = 0.91 CJSWG = 6.4E-11 PBSWG = 0.75
+MJSWG = 0.91 CF = 0 PVTH0 = 5.98016E-3
+PRDSW = 14.8598424 PK2 = 3.73981E-3 WKETA = -0.0166514
+LKETA = -0.0282038 )
*

* SPICE Netlist for OPAMP

.SUBCKT opamp2 GND VDD Ibias Vin+ Vin- Vout
M1 N3 Vin+ N2 VDD modp w=100u L=0.5u AS='1.1u*100u' AD='1.1u*100u' PS='100u+2.2u' PD='100u+2.2u'
M2 N4 Vin- N2 VDD modp w=100u L=0.5u AS='1.1u*100u' AD='1.1u*100u' PS='100u+2.2u' PD='100u+2.2u'
M3 N3 N3 0 0 modn w=100u L=1u AS='1.1u*100u' AD='1.1u*100u' PS='100u+2.2u' PD='100u+2.2u'
M4 N4 N3 0 0 modn w=100u L=1u AS='1.1u*100u' AD='1.1u*100u' PS='100u+2.2u' PD='100u+2.2u'
M5 N2 Ibias VDD VDD modp w=200u L=1u AS='1.1u*200u' AD='1.1u*200u' PS='200u+2.2u' PD='200u+2.2u'
M6 Vout N4 0 0 modn w=800u L=1u AS='1.1u*800u' AD='1.1u*800u' PS='800u+2.2u' PD='800u+2.2u'
M7 Vout Ibias VDD VDD modp w=800u L=1u AS='1.1u*800u' AD='1.1u*800u' PS='800u+2.2u' PD='800u+2.2u'
M8 Ibias Ibias VDD VDD modp w=100u L=1u AS='1.1u*100u' AD='1.1u*100u' PS='100u+2.2u' PD='100u+2.2u'
C1 N4 Vout 4pf
.ENDS

* Main circuit : Opamp2_settle_test

.ic v(vout)=2 v(vin)=2
.include tsmc.mod
.options accurate=1 abstol=1e-15
.plot tran v(Vout) v(Vin)
.tran 0.1ns 1.5us
xopamp2_1 0 VDD Ibias Vin Vout Vout opamp2
CL Vout 0 10pF

I1 Ibias 0 100u
vdd VDD 0 3.0
V1 Vin 0 pulse (2 1 200ns)

.END

supercede, change your pulse source from (2 1 200ns) to (3 0 200ns)

Hi Srijesh:

Thanks a lot. It turns out to be something I need

I realized that when V1 is either 1v or 2v, M1 is always turns off and will not change the output voltage. It is right?

By the way, could I use the same configuration to measure the slew rate, by calculating the slope of output voltage response?

Yep, that is true. You could possibly fine tune your Overdrive by appropriate sizing.
About the slew rate, i see the loading is about 14pf. Is that what you would see in actual scenario??[/u]

This is not an actual scenario. I am a beginner in analog field and it's a toy simulation. The 14pf is divided into two parts: 4pf is used as compensation capacitor, and connected to drain of M2, 10pf is the supposed load.

Could you elaborate a little on the "overdrive by appropriate sizing"? Is there any principle to follow. I am headache on that in these two days when I design the gain of the amplifier.

Hi supercede,

Looking at your opamp netlist, you have Vin+ and Vin- swapped.
Thus when you connect it in your main circuit netlist, you have positive feedback.
Fixing this should clear up a lot of things!

Also, I think what srijesh is referring to is the overdrive voltage of the transistors (Vgs-Vth). By keeping these consistent, you maintain a consistent gm/Id. Judging from the sizing, you may have room for optimization here.

what are your design specifications. mind putting it up.

why does the initial condition gives different response. if i remove it..the reponse is totally different.