Continue to Site

Welcome to EDAboard.com

Welcome to our site! EDAboard.com is an international Electronics Discussion Forum focused on EDA software, circuits, schematics, books, theory, papers, asic, pld, 8051, DSP, Network, RF, Analog Design, PCB, Service Manuals... and a whole lot more! To participate you need to register. Registration is free. Click here to register now.

[SOLVED] Simple Model of Lithium-Ion Battery (PSpice)

Status
Not open for further replies.

d123

Advanced Member level 5
Joined
Jun 7, 2015
Messages
2,505
Helped
494
Reputation
992
Reaction score
525
Trophy points
1,393
Location
Spain
Activity points
27,148
Hi,

I've looked at four different schematics - three in pdfs - of Li-Ion models and can't get them to work at all and don't really understand the requirements from the pdfs or png. That's the difference between me, hobbyist and you, engineer...

Two questions:

1) Has anybody used this model? Just wanted feedback if anyone has on how adequate it is for approximate simulation purposes.

Simple Model of Lithium-Ion Battery (PSpice)

2) If anyone has it, could you please send me a copy by PM to save me having to create a LinkedIn profile just to download it? I understand that a PSpice model is perfectly Tina-compatible.

Thanks.
 

Hi FvM,

Not yet, I'll take a look at that site later, thanks.
 

Netlists for Synosys HSPICE translated from LTspice.

"MEC201.sub"
Code:
.SUBCKT MEC201 PLUS MINUS c=0.001 soc=1 ns=1 tscale=60
E_Erate N8 0 VOL='I(V_batt)/C'
E_Ens N5 N1 N4 N1 'NS'
C_CT_S N7 N6 '(Cts/C)/Tscale'
E_Eloss SOC N3 PWL(1) rate 0
+0.33,-0.1 1.65,0.08 3.3,0.16 16.5,0.3 25,0.4 40,0.51
R_Rself SOC0 0 10MEG
C_CT_L PLUS N7 '(Ctl/C)/Tscale'
V_batt MINUS N1 0Vdc
E_Esoc SOC 0 VOL='V(SOC0,0)' MIN=-0.1 MAX=1
R_RT_L PLUS N7 'NS*Rtl/C'
R_RS N6 N5 'NS*Rs/C'
R_R1 N8 RATE 1
X_U1 N3 N4 N1 ETABLE
C_C_capacity SOC0 0 '(3600*C)/Tscale'
.IC V(SOC0)='SOC'
R_RT_S N7 N6 'NS*Rts/C'
C_C1 RATE 0 '3/Tscale'
G_G1 SOC0 0 CUR='I(V_batt)'
.Param rs=0.027 rtl=0.00095 ctl=15000 rts=0.00035 cts=1800
.ENDS MEC201

.SUBCKT ETABLE 1 2 3
R1 1 0 10MEG
E1 2 3 PWL(1) 1 0
+0.0010,0.100 0.0024,1.600 0.0037,2.700 0.0052,3.220
+0.0061,3.360 0.0075,3.480 0.0098,3.600 0.0130,3.700
+0.0185,3.785 0.0290,3.840 0.0400,3.860 0.0600,3.885
+0.1000,3.893 0.2000,3.900 0.3000,3.905 0.4000,3.912
+0.5000,3.925 0.6000,3.945 0.7000,3.973 0.8000,4.000
+0.9000,4.030 1.0000,4.060 1.1000,4.094
.ENDS

"test_MEC201_Charge.spi"
Code:
** Generated for: hspiceD
** Generated on: Dec  3 11:20:58 2018
** Design library name: My_Tools_TestBenches
** Design cell name: test_MEC201_Charge
** Design view name: schematic
.PARAM soc=0 cah=0.001 n=1 rate=10

.PROBE TRAN
+    V(h1)
+    V(xu1.soc)
+    I(vibatt)
.TRAN 100e-3 60.0
.OPTION DELMAX=100e-3


.TEMP 25.0
.OPTION
+    ACCURATE
*+    ACOUT=0
+    LIST=3
+    ARTIST=2
+    INGOLD=2
+    INTERP
+    METHOD=GEAR
+    NOMOD
+    PARHIER=LOCAL
+    PROBE
+    PSF=2
+    RUNLVL=6

** Library name: My_Tools_TestBenches
** Cell name: test_MEC201_Charge
** View name: schematic
.include 'MEC201.sub'
.model dmod d (n=0.01)

xu1 net1 0 MEC201 SOC=soc Ns=n Tscale=60
voch net011 0 DC='4.1*n-7e-3'
vin net06 0 DC=6
g0 net06 h1 VCCS net06 h1 100e3 MAX='rate*cah' MIN=0
vibatt h1 net1 DC=0
d1 h1 net011 dmod n=10e-3
.END

"test_MEC201_DisCharge.spi"
Code:
** Generated for: hspiceD
** Generated on: Dec  3 11:21:24 2018
** Design library name: My_Tools_TestBenches
** Design cell name: test_MEC201_DisCharge
** Design view name: schematic
.PARAM soc=1 cah=0.001 n=1 rate=0.33

.PROBE TRAN
+    I(vsense)
+    V(h1)
+    V(xu1.soc)
.TRAN 100e-3 200.0
+ sweep rate poi 6 0.33 1.65 3.3 16.5 35 40 
.OPTION DELMAX=100e-3

.TEMP 25.0
.OPTION
+    ACCURATE
*+    ACOUT=0
+    LIST=3
+    ARTIST=2
+    INGOLD=2
+    INTERP
+    METHOD=GEAR
+    NOMOD
+    PARHIER=LOCAL
+    PROBE
+    PSF=2
+    RUNLVL=6

** Library name: My_Tools_TestBenches
** Cell name: test_MEC201_DisCharge
** View name: schematic
.include 'MEC201.sub'

xu1 h1 0 MEC201 SOC=soc Ns=n Tscale=60
g0 net06 0 VCCS net06 0 100e3 MAX='rate*cah' MIN=0
vsense h1 net06 DC=0
.END
 

Attachments

  • ips_thinergy_mec201_product_data_sheet_ds1012_v1-1_final_20110920_1lqt.pdf
    1.9 MB · Views: 321
  • 200216-152340.png
    200216-152340.png
    56.7 KB · Views: 608
  • 200216-153902.png
    200216-153902.png
    48.3 KB · Views: 790
Last edited:
  • Like
Reactions: d123

    d123

    Points: 2
    Helpful Answer Positive Rating
Hi,

That's very kind of you, thank you very much.
 

Status
Not open for further replies.

Similar threads

Part and Inventory Search

Welcome to EDABoard.com

Sponsor

Back
Top