Implementation of the ZVN2106G Spice Model in Cadence Spectre

Hello everyone.
I am trying to include the ZVN2106G Spice Model in Cadence Spectre. The ZVN2106G Spice Model is in the attachment. The model is defined as a SPICE subcircuit. To include the Spice Model I tried the following:

1) I add a scasubckt from the analogLIb
2) Tell Spectre that the ZVN2106G subcircuit is not in the Spectre format.

simulator lang = spice

ZVN2106G Spice Model

simulator lang = spectre

But when I try ti simulate the circuit in Spectre, I´ll get error messages. The simulation log file is shown in the attachment. I´m interested in the error messages (CMI-2078) that corresponds to the voltage controlled switches in the spice file. How can I eliminate these error messages ?

Could anyone suggest a solution?

Thanks for your help !

View attachment ZVN2106G.txt

I don't use Cadence but I have used the ZVN2106G Spice model (with SIMetrix) and it works fine, so the problem must be something with the setup in Cadence. I am sorry I cannot be any help.

Keith.

Yes I know. I used the model also in SIMetrix and the simulation works fine. But the problem is that I need the ZVN2106G Spice model in Cadence Spectre as an external component. Thanks for your reply.

Sux

Why don't you try another way?I will give you just an idea to try,since i've never done something similar.
As far as i know,if somebody wants to create a model for a component,under Cadence's Environment,he must write a .scs file with the model description and parameters in this and then include it
from the top menu of ADE L (Tools-->Model Libraries).
So,maybe you should just change the extension of the above text file from .txt to .scs and follow the flow i gave you above,if and only if the code in your file is compatible with .scs format needed by spectre.

Take also a look under Cadence's installation doc folders on your hard disk to see if there is a documentation about this procedure.

Thanks for your solution. But the above spice model is not compatible with .scs format. My question is, what I have to do to make it compatible to Spectre format ? The problem is in the VSWITCH statement in the spice model. I have already included Spice models to spectre, but they did not have voltage controlled switches. Does anyone know in which way I can adapt the Spice model to make it compatible with Spectre ?

Thanks !

You could try putting brackets around it such as

.MODEL SMOD1 VSWITCH(RON=.001 ROFF=100 VON=3.5 VOFF=2.5)

I am surprised though - the VSWITCH syntax is fairly standard.

Keith.

Sux said:

... the above spice model is not compatible with .scs format.

Click to expand...

This shouldn't matter if you prepend the line simulator lang = spice. Try as jimito suggested above!

I can try jimito´s procedure. But the problem is that I can´t change easily the .txt file to .scs. The .txt file is in Spice syntax.

Sux said:

I can try jimito´s procedure. But the problem is that I can´t change easily the .txt file to .scs. The .txt file is in Spice syntax.

Click to expand...

Just rename the extension from .txt to .scs . The SPICE syntax in the file will be understood correctly by SPECTRE with the prepended simulator lang = spice line!

I followed jimito´s procedure. But the error messages are still the same. What does the error CMI-2078 stand for ? I have only problems by including spice models into spectre when there are voltage controlled switches. It is always the error CMI-2078. Do you have any idea in which way I must modify the spice model to include it in Spectre ?

Thanks !

Sux said:

It is always the error CMI-2078. Do you have any idea in which way I must modify the spice model to include it in Spectre ?

Click to expand...

I've dug into, a little bit: CMI means "Compiled Model Interface" and the error message is exactly what it is telling verbosely: Required parameter 'file' missing.

So I think "VSWITCH" isn't a known SPICE model, but an HDL component, so SPECTRE calls the CMI, but doesn't find the VSWITCH component HDL description. I've found this description in the "global.ncf" (from Calibre mgc flow) file below; try to include it somehow, perhaps also as .scs file. I had to rename it to "global.txt" here:
View attachment global.txt

The ZVN2106G Spice Model in Cadence Spectre

I know this thread is pretty old but i stumbled onto this same problem few days ago and after several days of browsing and not finding a solution anywhere i came up with one and wanted to post it just in case it saves time for someone else.

Shortly put as mentioned above the translator that translates spice models for the spectre simulator does not recognize VSWITCH as a definition for a voltage controlled switch. The go around i used is to more or less to add sections in the spice model that contain spectre language.

Ex: Spice definitions of a switch:

S1 2 15 14 13 SMOD1a

.MODEL SMOD1a VSWITCH RON=1e-2 ROFF=1e4 VON=-1.75 VOFF=2.75

Spectre definition:

S1 (2 15 14 13) SMOD1a
model SMOD1a relay vt1=-1.75 vt2=2.75 ropen=1e-2 rclosed=1e4

As you can see there are some major differences in the difinitions.

As long as the spectre definition is inserted in the spice model correctly (by using simulator lang = spectre), it will work.

here is the complete model for the ZXM61N02F transistor, extracts from which i used above (the same principle can be used to edit the model in the original post). A side note: in order to use a model with the "nmos" devide from "analogLib" cadence library the model must have 4 ports (the bulk is shorted to the source but nonetheless there should be a port in the model). This is why i added net 888 in the model description - its not connected anywhere its just there so spectre doesn't give and error.

-----------------------------------------------------------------------------
simulator lang=spice
*
*ZETEX ZXMN61N02F Spice Model v1.0 Last Revised 24/2/04
*
.subckt ZXM61N02F 3 4 5 888
*----connections----D-G-S
*
simulator lang=spice
M1 6 20 8 8 MOSMOD
M2 6 20 8 8 MOSMODS
RG 4 2 6
RIN 2 8 200e6
RL 3 5 35E6
C1 2 8 158E-12
C3 15 14 175E-12
C4 16 8 183E-12
D1 5 3 DMOD1
D2 17 3 DMOD2
Egs1 2 17 2 8 1
Egs2 13 8 2 8 1
Eds1 14 8 3 8 1
Egt1 2 20 21 8 -1
Vgt1 8 22 1
Igt1 8 21 1

simulator lang=spectre
S1 (2 15 14 13) SMOD1a
S2 (13 15 14 13) SMOD1b
S3 (16 13 13 8) SMOD2a
S4 (16 2 13 8) SMOD2b
RD (3 6) RMOD1 r=0.03
RS (8 5) RMOD1 r=0.0225
Rgt (21 22) RMOD2 r=1

simulator lang=spice
.model MOSMOD nmos vto=1.35 is=1E-15 kp=5.5 cbd=90E-12 lambda=4.9E-3
.model MOSMODS nmos vto=0.95 is=1E-15 kp=0.055
.model DMOD1 diode is=1E-13 rs=0.15 bv=24 ibv=1E-6 tt=9e-9
.model DMOD2 diode cjo=190e-12 is=1e-30 n=10

simulator lang=spectre
model SMOD1a relay vt1=-1.75 vt2=2.75 ropen=1e-2 rclosed=1e4
model SMOD1b relay vt1=2.75 vt2=-1.75 ropen=1e-2 rclosed=1e4
model SMOD2a relay vt1=-1.5 vt2=-3.5 ropen=1e2 rclosed=1e4
model SMOD2b relay vt1=-3.5 vt2=-1.5 ropen=1e-2 rclosed=1e4
model RMOD1 resistor tc1=2.5E-3 tc2=1.8E-5
model RMOD2 resistor tc1=3.3E-3 tc2=1.5E-6
simulator lang=spice

.ends ZXM61N02F
-----------------------------------------------------------------------------

As you can see there are 2 spectre language section inserted in the model that have simulator lang=spectre before and simulator lang=spice after. That way only the sections between these two lines are in spectre format.

Of course the text above needs to be saved in a text file with extension .scs
I am attaching the original purely spice model for comparison.

I hope my solution helps someone.