Continue to Site

Welcome to EDAboard.com

Welcome to our site! EDAboard.com is an international Electronics Discussion Forum focused on EDA software, circuits, schematics, books, theory, papers, asic, pld, 8051, DSP, Network, RF, Analog Design, PCB, Service Manuals... and a whole lot more! To participate you need to register. Registration is free. Click here to register now.

ltspice ploting internal nodes or subcircuit nodes

Status
Not open for further replies.

doupg

Junior Member level 1
Joined
Oct 27, 2007
Messages
15
Helped
5
Reputation
10
Reaction score
5
Trophy points
1,283
Activity points
1,505
hi all,

I have a circuit netlist which I'm using for simulation in ltspice.

this netlist is saved as .cir so that when I open it with ltspice I can simulate it.

in this netlist there is a subcircuit (OPAMP3 in this case)

my question is if it is possible to plot voltages/currents of the nodes inside the subcircuit?

let's say for example the current flowing through RP1 or the voltage at internal node 104.

when I run the simulation in ltspice and then select "add traces" I can only see the external components and the currents flowing into the interface pins of the subcircuit.

so my question is if there is a way or a command to show internal values of a subcircuit.

attached the netlist as a zip file or copy the code below and save it as "OPAMP3_V_LIMIT.CIR"

just open with ltspice, then run and you can see what I mean.

thank you very much!



OPAMP3_V_LIMIT.CIR - OPAMP MODEL WITH OUTPUT VOLTAGE LIMITING
*
* SIGNAL SOURCE - TRIANGLE WAVE
VS 1 0 PWL(0MS 0V 25MS 1V 75MS -1V 100MS 0V)
*
* POWER SUPPLIES
VCC 10 0 DC +15V
VEE 11 0 DC -15V
*
R1 0 2 10K
R2 2 3 1000K
XOP 1 2 3 10 11 OPAMP3
*
*
* OPAMP MACRO MODEL (INTERMEDIATE LEVEL)
* WITH OUTPUT VOLTAGE LIMITING
* IN+ IN- OUT VCC VEE
.SUBCKT OPAMP3 1 2 81 101 102
Q1 5 1 7 NPN
Q2 6 2 8 NPN
RC1 101 5 95.49
RC2 101 6 95.49
RE1 7 4 43.79
RE2 8 4 43.79
I1 4 102 0.001
*
* OPEN-LOOP GAIN, FIRST POLE AND SLEW RATE
G1 100 10 6 5 0.0104719
RP1 10 100 9.549MEG
CP1 10 100 0.0016667UF
*
* VOLTAGE LIMITING
DP 10 105 DLIM
VP 101 105 DC 2.214V
DN 104 10 DLIM
VN 104 102 DC 2.214V
.model DLIM D(IS=1E-15)
*
*OUTPUT STAGE
EOUT 80 100 10 100 1
RO 80 81 100
*
* INTERNAL REFERENCE
RREF1 101 103 100K
RREF2 103 102 100K
EREF 100 0 103 0 1
R100 100 0 1MEG
*
.model NPN NPN(BF=50000)
*
.ENDS
*
* ANALYSIS
.TRAN 1MS 100MS
*
* VIEW RESULTS
*.PRINT TRAN V(3) v(1)
.PROBE
 

Attachments

  • OPAMP3_V_LIMIT.zip
    642 bytes · Views: 137
Last edited:

Go to the "control panel" (under tools). Select the "save defaults" tab. Tick "save subcircuit node voltages" and "... currents". Then you should see internal subcircuit nodes in the "plot settings" "add trace" dialogue after you run the simulation.

Keith.
 
thank you! your post was very helpful. now I can see the internal currents/voltages. best regards!
 

Status
Not open for further replies.

Part and Inventory Search

Welcome to EDABoard.com

Sponsor

Back
Top