32 bit hex to ASCII conversion code in Assembly

;-------------------------------------------------------------------------------------------------
	
	; R0 should point to the LSB byte of the 32bit number to be converted.BCD 
	; result is stored starting from BCD0(MSB) to BCD4(LSB). 

	H32BCD:    	LCALL dCNVa             ; Clear/load conversion buffers
			LCALL dCNVb             ; Convert first byte
			LCALL dCNVb
			LCALL dCNVb
			LCALL dCNVb             ; Convert fourth byte
			MOV R1,#dACCU+dBYTS     ; Pointer to converted bytes+1
			MOV R6,#dBYTS           ; Counter for 5 BCD coded bytes
			LCALL BCD_STOR
			RET

	BCD_STOR:   	NOP                     	; Store 5 BCD bytes in decreasing order @R1   
			MOV R0,#BCD0          	; Point to the BCD result area
	STORL:      	DEC   R1              
			MOV   A,@R1
			MOV   @R0,A             	; Store BCD value
			INC R0                  	; Increment result pointer
			DJNZ  R6,STORL
			RET

	dCNVa:      	MOV   A,#0
			MOV   dACCU+0,A      ; Init DEC conversion dACCU:=0 ; dREG1:=1
			MOV   dACCU+1,A
			MOV   dACCU+2,A
			MOV   dACCU+3,A
			MOV   dACCU+4,A
			MOV   dREG1+0,#1
			MOV   dREG1+1,A
			MOV   dREG1+2,A
			MOV   dREG1+3,A
			MOV   dREG1+4,A
			RET

	dCNVb:      	MOV   A,@R0             ; Convert Byte at R0 , & inc R0
			INC   R0
	DCNVb1:     	MOV   R2,A              	; Convert Byte ACC
			MOV   R6,#8             	; Convert R2 using dACCU and dREG1
	dCNV1:      	MOV   A,R2              	; Get bit from R2
			RRC   A
			MOV   R2,A
			JNC   dCNV2
			LCALL ADD1              	; If CY add dREG1 to dACCU using BCD
	dCNV2:      	LCALL DOUBL1            ; dREG1:=2*dREG1
			DJNZ  R6,dCNV1          ; Loop until all 8 bits done
			RET

	DOUBL1:     	MOV   A,dREG1+0         ; dREG1:=2*dREG1 , BCD coded 5 bytes
			ADD   A,dREG1+0
			DA    A
			MOV   dREG1+0,A
			MOV   A,dREG1+1
			ADDC  A,dREG1+1
			DA    A
			MOV   dREG1+1,A
			MOV   A,dREG1+2
			ADDC  A,dREG1+2
			DA    A
			MOV   dREG1+2,A
			MOV   A,dREG1+3
			ADDC  A,dREG1+3
			DA    A
			MOV   dREG1+3,A
			MOV   A,dREG1+4
			ADDC  A,dREG1+4
			DA    A
			MOV   dREG1+4,A
			RET

	ADD1:  	MOV   A,dACCU+0         ; dACCU:=dACCU+dREG1 , bcd coded 5 bytes
			ADD   A,dREG1+0
			DA    A
			MOV   dACCU+0,A
			MOV   A,dACCU+1
			ADDC  A,dREG1+1
			DA    A
			MOV   dACCU+1,A
			MOV   A,dACCU+2
			ADDC  A,dREG1+2
			DA    A
			MOV   dACCU+2,A
			MOV   A,dACCU+3
			ADDC  A,dREG1+3
			DA    A
			MOV   dACCU+3,A
			MOV   A,dACCU+4
			ADDC  A,dREG1+4
			DA    A
			MOV   dACCU+4,A
			RET

	;-----------------------------------------------------------------------------------------------------

void lcdoutulong(unsigned long lnum)
{
   unsigned char digit;

   while(lnum != 0)
   {
      digit = lum % 10;
      /* convert to ASCII '0' = 0x30 */
      digit = digit + '0'; 
      lcdoutdigit(digit);
      lnum = lnum / 10;
   }
}

*-----------------------------------------------------------
*
*	bin6bcd - routine compute from binary value to bcd
*
*	Entry:  reg_e:d - binary value (24 bit)
*
*	Exit:	reg_e:d - 8 bcd digits (0000:0000-1677:7215)
*
*-----------------------------------------------------------

BIN6BCD:
	PSHM	K,X,Z
	AIS	#-10
	TSZ				; scratchpad
	STE	0,Z
	STD	2,Z
	CLRW	4,Z
	CLRW	6,Z
	CLRW	8,Z
	LDAA	#24
	STAA	8,Z			; counter

BIN46BCD:
	LDAB	#.HIGH4.BINXBCDTAB
	TBXK
	LDX	#.LOW16.BINXBCDTAB

BIN46BCD1:
	RORW	0,Z
	RORW	2,Z
	BCC	BIN46BCD2		; not set!
	LDAA	3,X
	ADDA	7,Z
	DAA
	STAA	7,Z
	LDAA	2,X
	ADCA	6,Z
	DAA
	STAA	6,Z
	LDAA	1,X
	ADCA	5,Z
	DAA
	STAA	5,Z
	LDAA	0,X
	ADCA	4,Z
	DAA
	STAA	4,Z			; add in bcd value for bit

BIN46BCD2:
	AIX	#4
	DEC	8,Z
	BNE	BIN46BCD1
	LDE	4,Z
	LDD	6,Z			; result in e:d
	AIS	#10
	PULM	K,X,Z
	RTS

BINXBCDTAB:
	DB	$00,$00,$00,$01		; bit  0
	DB	$00,$00,$00,$02		; bit  1
	DB	$00,$00,$00,$04		; bit  2
	DB	$00,$00,$00,$08		; bit  3
	DB	$00,$00,$00,$16		; bit  4
	DB	$00,$00,$00,$32		; bit  5
	DB	$00,$00,$00,$64		; bit  6
	DB	$00,$00,$01,$28		; bit  7
	DB	$00,$00,$02,$56		; bit  8
	DB	$00,$00,$05,$12		; bit  9
	DB	$00,$00,$10,$24		; bit 10
	DB	$00,$00,$20,$48		; bit 11
	DB	$00,$00,$40,$96		; bit 12
	DB	$00,$00,$81,$92		; bit 13
	DB	$00,$01,$63,$84		; bit 14
	DB	$00,$03,$27,$68		; bit 15
	DB	$00,$06,$55,$36		; bit 16
	DB	$00,$13,$10,$72		; bit 17
	DB	$00,$26,$21,$44		; bit 18
	DB	$00,$52,$42,$88		; bit 19
	DB	$01,$04,$85,$76		; bit 20
	DB	$02,$09,$71,$52		; bit 21
	DB	$04,$19,$43,$04		; bit 22
	DB	$08,$38,$86,$08		; bit 23